#-------------------------------------------------
#
# Project created by QtCreator 2018-03-07T02:18:16
#
#-------------------------------------------------

QT       += core gui multimedia

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET = game
TEMPLATE = app
CONFIG += c++14

# The following define makes your compiler emit warnings if you use
# any feature of Qt which has been marked as deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

INCLUDEPATH += $$PWD/include/
INCLUDEPATH += $$PWD/ui/

# ================================================== #

win32 {
    build_pass: CONFIG(debug, debug|release) {
        DESTDIR = $$OUT_PWD/debug
    }
    else: build_pass {
        DESTDIR = $$OUT_PWD/release
    }
}

unix {
    DESTDIR = $$OUT_PWD
}

guiRes.target = BuildResources
exists($$DESTDIR/res) {
        message("Directory $$DESTDIR/res already exists")
    } else {
            guiRes.commands += $(MKDIR) \"$$DESTDIR/res\" $$escape_expand(\n\t)
    }

win32 {
    guiRes.commands += rcc.exe -binary $$PWD/res/hotseatgame/game_ui.qrc -o $$DESTDIR/res/game_ui_data.gtr $$escape_expand(\n\t) \
                       rcc.exe -binary $$PWD/res/hotseatgame/units.qrc -o $$DESTDIR/res/unit_data.gtr $$escape_expand(\n\t) \
                       rcc.exe -binary $$PWD/res/hotseatgame/effects.qrc -o $$DESTDIR/res/effect_data.gtr $$escape_expand(\n\t) \
                       rcc.exe -binary $$PWD/res/hotseatgame/spells.qrc -o $$DESTDIR/res/spell_data.gtr
}

unix {
    guiRes.commands += rcc -binary $$PWD/res/hotseatgame/game_ui.qrc -o $$DESTDIR/res/game_ui_data.gtr $$escape_expand(\n\t) \
                       rcc -binary $$PWD/res/hotseatgame/units.qrc -o $$DESTDIR/res/unit_data.gtr $$escape_expand(\n\t) \
                       rcc -binary $$PWD/res/hotseatgame/effects.qrc -o $$DESTDIR/res/effect_data.gtr $$escape_expand(\n\t) \
                       rcc -binary $$PWD/res/hotseatgame/spells.qrc -o $$DESTDIR/res/spell_data.gtr
}

QMAKE_EXTRA_TARGETS += guiRes
PRE_TARGETDEPS += BuildResources

# ================================================== #
SOURCES +=                                      \
    source/main.cpp                             \
    source/cell.cpp                             \
    source/playermanager.cpp                    \
    source/race.cpp                             \
    source/racemanager.cpp                      \
    source/soundengine.cpp                      \
                                                \
    source/effects/effect.cpp                   \
    source/effects/melledamage.cpp              \
    source/effects/selfheal.cpp                 \
                                                \
    source/gui/guiscenemanager.cpp              \
    source/gui/scene.cpp                        \
                                                \
    source/hotseatgame/raceicon.cpp             \
    source/hotseatgame/uniticon.cpp             \
    source/hotseatgame/gamemanager.cpp          \
    source/hotseatgame/unitsqueue.cpp           \
                                                \
    source/skills/spell.cpp                     \
    source/skills/selfheal.cpp                  \
    source/skills/melledamage.cpp               \
                                                \
    source/units/mage.cpp                       \
    source/units/unit.cpp                       \
    source/units/warrior.cpp                    \
                                                \
    ui/hotseat_game/hotseatgame.cpp             \
    ui/hotseat_intro/playervsplayerintro.cpp    \
    ui/hotseat_prebattle/prebattlescene.cpp     \
    ui/hotseat_recruitment/recruitmentscene.cpp \
    ui/loading_form/loadingform.cpp             \
    ui/main_menu/mainmenu.cpp                   \

HEADERS +=                                      \
    include/abstractfactory.h                   \
    include/cell.h                              \
    include/player.h                            \
    include/playermanager.h                     \
    include/race.h                              \
    include/racemanager.h                       \
    include/soundengine.h                       \
                                                \
    include/effects/effect.h                    \
    include/effects/melledamage.h               \
    include/effects/selfheal.h                  \
                                                \
    include/gui/guiscenemanager.h               \
    include/gui/scene.h                         \
                                                \
    include/hotseatgame/gamemanager.h           \
    include/hotseatgame/raceicon.h              \
    include/hotseatgame/uniticon.h              \
    include/hotseatgame/unitsqueue.h            \
                                                \
    include/skills/melledamage.h                \
    include/skills/selfheal.h                   \
    include/skills/spell.h                      \
                                                \
    include/units/mage.h                        \
    include/units/unit.h                        \
    include/units/warrior.h                     \
                                                \
    ui/hotseat_game/hotseatgame.h               \
    ui/hotseat_intro/playervsplayerintro.h      \
    ui/hotseat_prebattle/prebattlescene.h       \
    ui/hotseat_recruitment/recruitmentscene.h   \
    ui/loading_form/loadingform.h               \
    ui/main_menu/mainmenu.h

FORMS +=                                        \
    ui/hotseat_game/hotseatgame.ui              \
    ui/hotseat_intro/playervsplayerintro.ui     \
    ui/hotseat_prebattle/prebattlescene.ui      \
    ui/hotseat_recruitment/recruitmentscene.ui  \
    ui/loading_form/loadingform.ui              \
    ui/main_menu/mainmenu.ui

RESOURCES += \
     res/GUI.qrc \
     res/hotseatgame/game_ui.qrc \
     res/hotseatgame/units.qrc \
     res/hotseatgame/spells.qrc \
     res/hotseatgame/effects.qrc \
     res/main_menu.qrc \
     res/loading_form.qrc

RC_ICONS = $$PWD/assets/common/icon.ico